//声明是Android应用程序
apply plugin: 'com.android.application'
android {
compileSdkVersion 23 //编译SDK的版本
buildToolsVersion "23.0.3"//SDK目录下build-tools目录下可以查找，包括打包常用的appt，dx工具
defaultConfig {
applicationId "gradle.mine.com"//应用程序的唯一识别，和packagename有所区别
minSdkVersion 15 //最小SDK，如果Android设备的系统小于这个版本将无法安装
targetSdkVersion 23 //目标SDK，如果系统刚好是这个sdk就不进行兼容性检查，运行效率加快
versionCode 1 //版本号
versionName "1.0"//版本名称
}
signingConfigs {
release {
storeFile file('demo.keystore')
storePassword 'demo'
keyAlias 'demo'
keyPassword 'demo'
}
}
buildTypes {
release { //release版本的配置
zipAlignEnabled true //zip压缩
shrinkResources true // 移除无用的resource文件
minifyEnabled true //是否进行混淆
proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
//release的Proguard默认为Module下的proguard-rules.pro文件.
debuggable false //是否支持调试
//采用动态替换字符串的方式生成不同的release.apk
applicationVariants.all { variant ->
variant.outputs.each { output ->
def outputFile = output.outputFile
if (outputFile != null && outputFile.name.endsWith('release.apk')) {
def timeStamp = new Date().format('yyyyMMddHH');
def fileName = "demo-${defaultConfig.versionName}" + "-" + timeStamp + "-lj-" + ".apk";
output.outputFile = file("${outputFile.parent}/${fileName}")
}
}
}
jniDebuggable false //关闭jni调试
}
debug {//debug版本的配置
minifyEnabled false
zipAlignEnabled true
shrinkResources true // 移除无用的resource文件
proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
debuggable true
jniDebuggable true
}
}
//默认的一些文件路径的配置
sourceSets {
main {
assets.srcDirs = ['assets'] //资源文件
jni.srcDirs 'src/main/jni' //jni文件
jniLibs.srcDir 'src/main/jniLibs' //jni库
aidl.srcDirs = ['src']
}
}
//程序在编译的时候会检查lint，有任何错误提示会停止build，我们可以关闭这个开关
lintOptions {
abortOnError false //即使报错也不会停止打包
checkReleaseBuilds false //打包release版本的时候进行检测
}
compileOptions {
sourceCompatibility JavaVersion.VERSION_1_7 //JDK的配置
targetCompatibility JavaVersion.VERSION_1_7
}
productFlavors {
//在这里你可以设置你的产品发布的一些东西，
//比如你现在一共软件需要发布到不同渠道，
//且不同渠道中的包名不同，那么可以在此进行配置；
//甚至可以设置不同的 AndroidManifest.xml 文件。
flavor1 {
packageName='gradle.mine.com01'
manifest.srcFile 'GradleDemo/AndroidManifest1.xml'
}
flavor2 {
packageName='gradle.mine.com02'
manifest.srcFile 'GradleDemo/AndroidManifest2.xml'
}
googlePlay {
}
}
productFlavors.all {
flavor -> flavor.manifestPlaceholders = [UMENG_CHANNEL_VALUE: name]
}
//所谓ProductFlavors其实就是可定义的产品特性，
//配合 manifest merger 使用的时候就可以达成在一次编译
//过程中产生多个具有自己特性配置的版本。
//上面这个配置的作用就是，为每个渠道包产生不同的 UMENG_CHANNEL_VALUE 的值。
}
dependencies {
compile fileTree(dir: 'libs', include: ['*.jar'])//这句话也就是说编译时依赖 libs 文件夹下的所有 jar 文件
// compile project(':library') //依赖本地library库
testCompile 'junit:junit:4.12'
compile 'com.android.support:appcompat-v7:23.3.0'//依赖远程库
} |
